Fix File.flush return value for case of zero bytes to flush.

Author: jemc

packages/files/_test.pony

@@ -39,6 +39,7 @@ actor Main is TestList
     test(_TestFileQueuev)
     test(_TestFileMixedWriteQueue)
     test(_TestFileWritevLarge)
+    test(_TestFileFlush)
 
 primitive _FileHelper
   fun make_files(h: TestHelper, files: Array[String]): FilePath ? =>
@@ -775,3 +776,39 @@ class iso _TestFileWritevLarge is UnitTest
     else
       h.fail("Unhandled error!")
     end
+
+class iso _TestFileFlush is UnitTest
+  fun name(): String => "files/File.flush"
+
+  fun tag _expect_file_size(
+    h: TestHelper,
+    path: FilePath,
+    size: USize,
+    loc: SourceLoc = __loc)
+    ?
+  =>
+    with file = CreateFile(path) as File do
+      h.assert_eq[USize](size, file.size() where loc = loc)
+    end
+
+  fun apply(h: TestHelper) =>
+    try
+      let path = FilePath(h.env.root as AmbientAuth, "tmp.flush")?
+      with file = CreateFile(path) as File do
+        // Flush with no writes succeeds trivially, but does nothing.
+        h.assert_true(file.flush())
+
+        file.queue("foobar\n")
+
+        // Without flushing, the file size is still zero.
+        _expect_file_size(h, path, 0)?
+
+        h.assert_true(file.flush())
+
+        // Now expect to see the correct file size.
+        _expect_file_size(h, path, 7)?
+      end
+      path.remove()
+    else
+      h.fail("Unhandled error!")
+    end

packages/files/file.pony

@@ -461,19 +461,22 @@ class File
     """
     Write pending data.
     Returns false if the file wasn't opened with write permission.
-    Returns raises error if not all the bytes were written.
+    Raises an error if not all the bytes were written.
     Returns true if it sent all pending data.
     Returns num_processed and new pending_total also.
     """
-    // TODO: Make writev_batch_size user configurable
-    let writev_batch_size = @pony_os_writev_max()
     var num_to_send: I32 = 0
     var num_sent: USize = 0
     var bytes_to_send: USize = 0
     var pending_total = _pending_writev_total
-    while
-      writeable and (pending_total > 0) and (_fd != -1)
-    do
+
+    if (not writeable) or (_fd == -1) then
+      return (false, num_sent, pending_total)
+    end
+
+    // TODO: Make writev_batch_size user configurable
+    let writev_batch_size = @pony_os_writev_max()
+    while pending_total > 0 do
       //determine number of bytes and buffers to send
       if (_pending_writev.size().i32()/2) < writev_batch_size then
         num_to_send = _pending_writev.size().i32()/2
@@ -500,20 +503,14 @@ class File
           num_to_send).isize()
       end
 
-      if len < bytes_to_send.isize() then
-        error
-      else
-        // sent all data we requested in this batch
-        pending_total = pending_total - bytes_to_send
-        num_sent = num_sent + num_to_send.usize()
+      if len < bytes_to_send.isize() then error end
 
-        if pending_total == 0 then
-          return (true, num_sent, pending_total)
-        end
-      end
+      // sent all data we requested in this batch
+      pending_total = pending_total - bytes_to_send
+      num_sent = num_sent + num_to_send.usize()
     end
 
-    (false, num_sent, pending_total)
+    (true, num_sent, pending_total)
 
   fun ref position(): USize =>
     """